(*Taken from:
Rachael L.Baumann
"Diffusion and Reaction in a Catalyst Pellet"
http://demonstrations.wolfram.com/DiffusionAndReactionInACatalystPellet/Wolfram Demonstrations Project
Published:October 31 2017
*)

particle=Graphics[{Thick,
{EdgeForm@Thick,FaceForm@GrayLevel@0.9,Disk[{0,0},0.1]},
PointSize@0.065,Point@{0,0},Point[0.1*{Cos[45°],Sin[45°]}],
Arrowheads@0.15,Arrow[{{0,0},0.1*{Cos[45°],Sin[45°]}}],Arrow[{{0,0},{0.06,0}}],
Text[Style["R",17,Italic],0.05*{Cos[45°],Sin[45°]},{2,-0.5}],
Text[Style["r",17,Italic],{0.06,0},{-1.5,0}],
Text[Style[Subscript[Style["C",Italic],"A, s"],17],0.1*{Cos[45°],Sin[45°]},{-1.5,0}]
},ImageSize->125,Background->White];

Manipulate[
Module[{ϕ,σ,τ,De,CAs,Φ,CA,M,η},
ϕ=0.4;σ=0.8;τ=3;De=D0*ϕ*σ/τ;CAs=0.04;
Φ=R*(Sqrt[k/De]);

CA[r_]:=CAs*(R/r)*((Sinh[Φ*r/R])/(Sinh[Φ]));

M=4*π*R*De*CAs*(Φ*Coth[Φ]-1);
η=(3/(Φ^2))*(Φ*Coth[Φ]-1);

Plot[CA[r],{r,0,R},PlotStyle->{Thick,Black},PlotRange->{0,CAs+0.008},PlotRangePadding->{None,{None,Scaled@0.1}},PlotRangeClipping->False,
Frame->True,FrameTicks->True,FrameLabel->{"catalyst pellet radius (cm)",Row@{"concentration (mmol/",Superscript["cm",3],")"}},LabelStyle->{17,Black},ImageSize->{600,400},AspectRatio->Full,ImagePadding->{{60,25},{60,5}},
Epilog->{
{Thick,Dashed,Line[{{0,CAs},{R,CAs}}]},
Text[Style[Row@{Subscript[Style["C",Italic],"A, s"]," = ",CAs," mmol/",Superscript["cm",3]},17],{R,CAs},{1.2,-1.1}],
Line[{{#,-0.003},{#,-0.006}}]&/@{0,R},
Text[Style[Row@{Style["r",Italic]," = ",0},17],{0,-0.006},{0,1}],
Text[Style[Row@{Style["r",Italic]," = ",Style["R",Italic]},17],{R,-0.006},{0,1}],
Text[Style[Column[{
Row@{"overall rate = ",NumberForm[M,{5,2}]," mmol/s"},
Row@{"Thiele modulus = ",NumberForm[Φ,{4,2}]},
Row@{"effectiveness factor = ",NumberForm[η,{2,2}]}
},Alignment->"="],17],{0.25*R,CAs+0.006}],
Inset[particle,Scaled@{0.85,0.2}]
}]
],
Grid[{
{Control[{{R,1,"pellet radius (cm)"},0.1,1,0.1,Appearance->"Labeled",ImageSize->Small}],SpanFromLeft,
Control[{{D0,10,Row@{"diffusivity (",Superscript["cm",2],"/s)"}},1,100,1,Appearance->"Labeled",ImageSize->Small}]},
{Control[{{k,15,"rate constant (1/s)"},5,45,1,Appearance->"Labeled"}],SpanFromLeft}
},Alignment->Left],
SaveDefinitions->True]

Just Evaluate Notebook! 

The plot produced is surface concentration vs catalyst pellet radius. What do you notice
happen to the surface concentration as pellet radius decreases? What does that mean for the concentration at
the center of the pellet? Further, what happens to the overall reaction rate if you decrease the rate constant?